Add latest version of signal-desktop-bin

2026-07-10 12:58:53 -04:00
parent 1e80f12a05
commit 99937d94dd
2 changed files with 95 additions and 0 deletions
--- a/net-im/signal-desktop-bin/signal-desktop-bin-8.18.0.ebuild
+++ b/net-im/signal-desktop-bin/signal-desktop-bin-8.18.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN/-bin/}"
+
+inherit pax-utils unpacker xdg
+
+DESCRIPTION="Allows you to send and receive messages of Signal Messenger on your computer"
+HOMEPAGE="https://signal.org/
+	https://github.com/signalapp/Signal-Desktop"
+SRC_URI="https://updates.signal.org/desktop/apt/pool/s/${MY_PN}/${MY_PN}_${PV}_amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="GPL-3 MIT MIT-with-advertising BSD-1 BSD-2 BSD Apache-2.0 ISC openssl ZLIB APSL-2 icu Artistic-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="-* amd64"
+RESTRICT="splitdebug"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	>=media-fonts/noto-emoji-20231130
+	media-libs/alsa-lib
+	media-libs/libpulse
+	media-libs/mesa[opengl]
+	net-print/cups
+	sys-apps/dbus
+	virtual/udev
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="
+	opt/Signal/chrome_crashpad_handler
+	opt/Signal/chrome-sandbox
+	opt/Signal/libEGL.so
+	opt/Signal/libGLESv2.so
+	opt/Signal/libffmpeg.so
+	opt/Signal/libvk_swiftshader.so
+	opt/Signal/libvulkan.so.1
+	opt/Signal/resources/app.asar.unpacked/node_modules/*
+	opt/Signal/signal-desktop
+	opt/Signal/swiftshader/libEGL.so
+	opt/Signal/swiftshader/libGLESv2.so"
+
+src_prepare() {
+	default
+	sed -e "s|^Exec=/opt/Signal/signal-desktop|Exec=${MY_PN}|" \
+		-i usr/share/applications/signal-desktop.desktop || die
+	unpack usr/share/doc/signal-desktop/changelog.gz
+
+	# https://github.com/signalapp/Signal-Desktop/issues/6239
+	# https://github.com/signalapp/Signal-Desktop/issues/6122
+	# fixes app icon issues on wayland because "app-id" is "signal"
+	# and desktop file needs to match
+	mv usr/share/applications/signal-desktop.desktop \
+		usr/share/applications/signal.desktop || die
+}
+
+src_install() {
+	insinto /
+	dodoc changelog
+	doins -r opt
+	insinto /usr/share
+
+	doins -r usr/share/applications
+	doins -r usr/share/icons
+	fperms +x /opt/Signal/signal-desktop /opt/Signal/chrome-sandbox /opt/Signal/chrome_crashpad_handler
+	fperms u+s /opt/Signal/chrome-sandbox
+	pax-mark m opt/Signal/signal-desktop opt/Signal/chrome-sandbox opt/Signal/chrome_crashpad_handler
+
+	dosym ../../opt/Signal/${MY_PN} /usr/bin/${MY_PN}
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "For using the tray icon on compatible desktop environments, start Signal with"
+	elog " '--start-in-tray' or '--use-tray-icon'."
+}