# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit webapp

DESCRIPTION="Kanboard is a free and open source Kanban project management software."
HOMEPAGE="https://kanboard.org/"
SRC_URI="https://github.com/kanboard/kanboard/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="amd64 ~ppc ~sparc ~x86"
IUSE="+apache2 +curl ldap mysql postgres +sqlite"
REQUIRED_USE="|| ( mysql postgres sqlite )"

DEPEND=""
RDEPEND="
	>=dev-lang/php-5.6[pdo,gd,json,hash,ctype,session,filter,xml,simplexml,zip]
	virtual/httpd-php:*
	apache2? (
		www-servers/apache[apache2_modules_version]
		dev-lang/php[apache2]
	)
	mysql? (
		>=virtual/mysql-5.6
		dev-lang/php[mysql]
	)
	postgres? (
		>=dev-db/postgresql-9.3:*
		dev-lang/php[postgres]
	)
	sqlite? (
		>=dev-db/sqlite-3.7
		dev-lang/php[sqlite]
	)
	curl? ( dev-lang/php[curl] )
	ldap? ( dev-lang/php[ldap] )
"

need_httpd_cgi

src_install() {
	webapp_src_preinst

	rm -f LICENSE
	rm -f Dockerfile*
	rm -f composer.*
	rm -f docker-compose.yml
	rm -f Vagrantfile
	rm -f ChangeLog

	touch config.php
	mkdir data

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_serverowned -R "${MY_HTDOCSDIR}"/data

	webapp_configfile "${MY_HTDOCSDIR}"/config.php

	webapp_src_install
}